SEDS Logo

From SEDSWiki

The first instance of a SEDS logo is documented early in Peter Diamandis's SEDS scrapbook from the SEDS Newsletter, Volume 1, #2 circa 1981. This logo was used for the first several years of SEDS on the newsletters and on letterhead.

Later on, other logos were experimented with such as this one and this one and this one.

A slight departure from the original logo which featured the Space Shuttle, this one featured an astronaut reminiscent of a "moon man" with a Saturn-like planet in the background as shown in this trifold and to the left featuring a quote from Carl Sagan "Students are the future, and the attitudes that students have about the direction of the space pgoram will ultimately determine . . . the direction of that program."

Some other doodles featuring logo ideas are also in Peter's scrapbook.

Sometime in the late 80's or early 90's, a line-art logo was introduced. While originally a two-dimensional black & white logo, it was expanded on by John Brownlee of the Univeristy of Arizona (vice president, UA SEDS & vice-chair SEDS-USA) using a ray-tracing program called POVRAY.

foto:26627

Many versions of this and other logos are available to browse at the SEDS Gallery. Feel free to make use of these logos, modify them for your chapter, and upload your modifications and creations.

The code for the ray-traced POVRAY logo is available below.

--Chris 21:17, 3 March 2006 (PST)

/* Created by John Brownlee, University of Arizona SEDS, January 1996 */
/* Updated and commented by Chris Lewicki, March 2006 */

#include "shapes.inc"
#include "colors.inc"
#include "textures.inc"

camera {orthographic location <18,0,-35> look_at <18,0,0> }
light_source { <-150,150,-450> color rgb <2,2,2>  }


#declare Logotexture = texture {
			pigment {color rgb <0,0,1>}
			finish { 
				phong 1.4 phong_size 150 
				specular .1 roughness .1
				metallic .005
				ambient 0
			}
		}

#declare Halfcurve = object {
		torus { 3,1.2 
			texture { Logotexture }
			clipped_by {plane {x,0}}
			rotate <90,0,0>
			sturm
		}
	}
#declare Fullcurve = object {
		torus {6,1.2
			texture { Logotexture}
			clipped_by {plane {x,0}}
			rotate <90,0,0>
			scale <1.2,1,1>
			sturm
			}
	}

#declare Ess = union{
	
/* Left top part of "S" */
object {Halfcurve
	translate <0,3,0>
}
/* Right bottom part of "S" */
object {Halfcurve	
	rotate <0,0,-180>
	translate <3,-3,0>	
}

/* Middle-straight part of "S" */
cylinder { <0,0,0>, <3,0,0>, 1.2
	texture {Logotexture}
	}

/* Bottom-straight part of "S" */
cylinder {<3,-6,0>, <-3,-6,0>, 1.2
	texture {Logotexture}
	}
/* End cap on bottom-left of "S" */
sphere {<-3,-6,0>,1.2 texture {Logotexture}}
}


#declare Logo = union {
object {Ess}

/* Top-straight part of left "S" */
cylinder {<0,6,0>, <20,6,0> , 1.2
	texture {Logotexture}
	}
/* Curve of "E" */
object {Fullcurve
	translate <16,0,0>
	}
/* Middle-line of "E" */
cylinder {<9,0,0>, <14,0,0>, 1.2
	texture {Logotexture}
	}

/* Round end-cap of middle part of "E" */
sphere {<14,0,0>,1.2 texture {Logotexture}}

/* Bottom part that joins the "E" and "D" */
cylinder {<16,-6,0>,<33,-6,0>,1.2
	texture {Logotexture}
	}

/* The right side of the "D" */
object {Fullcurve 
	rotate <0,180,0>
	translate <20,0,0>
	}

/* The left side (vertical line) of the "D" */
cylinder {<18,-6,0>, <18,6,0>, 1.2
	texture {Logotexture}
	}

/* Copy of left "S" to right "S" */
object {Ess
	translate <33,0,0>
}
/* Top part of right "S" */
cylinder { <33,6,0>, <39,6,0>, 1.2 texture {Logotexture}}

/* End-cap of right "S"  */
sphere {<39,6,0>,1.2 texture {Logotexture}}

}

object {Logo}